#!/usr/bin/gnuplot
# gnuplot 


# Allgemeines zu den Eingabedaten
set timefmt "%d.%m.%Y"     # Zeitangaben in TT.MM.YYYY
set datafile separator ";" # Spaltenseparator 


# Allgemeines zur Ausgabe
unset key
set style data lines
set style fill transparent solid 0.4
set grid


# Bereiche/Format/etc X-Achse 
set xdata time
set xlabel 'Jahr'
set xrange ['30.06.1807':'30.06.2009']
set xtics '01.01.1800', 60 * 60 * 24 * 365.25 * 25
                      #  xtics in Sekunden 
                      # der Beginn der X-Einteilung kann außerhalb xrange
                      # liegen
set mxtics 5
set format x '%Y'     # Beschriftungsformat JJJJ


# Bereiche/Format/etc Y-Achse
set ylabel 'Einwohnerzahl'
set yrange [0:]
set ytics 50000
set decimalsign locale "de_DE.utf8"
set decimal     locale "de_DE.utf8"
set format y  "%'.0f"  # Ausgabeformat
set mytics 5


# Ausgabeformat: Wir erzeugen SVG
# Die Ausgabedaten leiten wir in eine Pipe und sind so bei Namen der
# Ausgabedatei flexibel (Aufruf: Progname.plt > Ausgabe-svg)
set term svg size 800,400 font "Arial,14"
# keine "set output '<Dateiname>'" Angabe


# Erzeugen der Ausgabe 
plot '-' using 1:($2) with filledcurves below x1 lt rgb 'dark-blue' lw 2,\


# Quelle:
# https://de.wikipedia.org/wiki/Lublin#Einwohnerentwicklung
#
30.06.1807;7082
30.06.1814;12500
30.06.1829;15800
30.06.1870;21346
30.06.1900;57237
30.06.1914;83126
30.06.1939;122000
30.06.1946;99400
30.06.1970;238500
30.06.1980;304400
30.06.1990;351400
30.06.2000;355800
30.06.2004;355998
30.06.2006;354967
30.06.2007;353483
30.06.2009;349440
EOF