Datei:Butterworth response.svg
Originaldatei (SVG-Datei, Basisgröße: 512 × 384 Pixel, Dateigröße: 41 KB)
Diese Datei stammt aus Wikimedia Commons und kann von anderen Projekten verwendet werden. Die Beschreibung von deren Dateibeschreibungsseite wird unten angezeigt.
Beschreibung
BeschreibungButterworth response.svg |
English: This is the SVG version of the PNG image created by Omegatron.
I simply changed the terminal type from PostScript to SVG in the gnuplot script file. The frequency response of a Butterworth filter with logarithmic axes (Bode plot) and various labels. Cutoff frequency is normalized to 1 rad/s. Gain is normalized to 0 dB in the passband.
|
||||
Datum | (UTC) | ||||
Quelle | |||||
Urheber |
|
||||
Andere Versionen |
|
||||
gnuplot source InfoField | click to expand
set samples 2001
# set terminal postscript enhanced landscape color lw 2 "Times-Roman" 20
set terminal svg size 800 600 dynamic enhanced
set output "butterworth.svg"
# Butterworth amplitude response and decibel calculation. n is the order, which is just 1 in this image.
G(w,n) = 1 / (sqrt(1 + w**(2*n)))
dB(x) = 20 * log10(abs(x))
# Gridlines
set grid
# Set x axis to logarithmic scale
set logscale x 10
# Set range of x and y axes
set xrange [0.001:1000]
set yrange [-60:10]
# Create x-axis tic marks once per decade (every multiple of 10)
set xtics 10
# Use 10 x-axis minor divisions per major division
set mxtics 10
# Axis labels
set xlabel "Angular frequency (rad/s)"
set ylabel "Gain (dB)"
# No need for a key
set nokey #0.1,-25
# Frequency response's line plotting style
set style line 1 lt 1 lw 2
# Draw a separator between passband and stopband and label them
set style line 2 lt 2 lw 1
set style arrow 2 nohead ls 2
set arrow 3 from 1,-60 to 1,10 as 2
# Label coordinates are relative to the graph window, not to the function, centered at the 1/4 and 3/4 width points
set label 1 "Passband" at graph 0.25, graph 0.1 c
set label 2 "Stopband" at graph 0.75, graph 0.1 c
# Asymptote lines and slope lines are the same "arrow" style
set style line 3 lt 3 lw 1
set style arrow 3 nohead ls 3
# Draw asymptote lines
set arrow 1 from 1,0 to 1000,-60 as 3
set arrow 2 from .001,0 to 1,0 as 3
# -3 dB arrow style and arrow
set style line 4 lt 4 lw 1
set style arrow 4 head filled size screen 0.02,15,45 ls 4
set arrow 4 from 2,3 to 1,0 as 4
# "Cutoff frequency" label uses same coordinates as the function
set label 3 "Cutoff frequency" at 2,4 l
# "-3 dB" label
set arrow 5 from 0.5,-6 to 1,-3 as 4
set label 4 "-3.01 dB" at 0.5,-7 r
# Draw slope lines and label
set arrow 6 from 100,-20 to 12,-20 as 3
set arrow 7 from 100,-20 to 100,-39 as 3
set label 5 "Slope: -20 dB/decade" at 100,-18 c
# Plot the filter response
plot
dB(G(x,1)) ls 1 title "1st-order response"
unset output # cleanup the handle
|
Lizenz
- Dieses Werk darf von dir
- verbreitet werden – vervielfältigt, verbreitet und öffentlich zugänglich gemacht werden
- neu zusammengestellt werden – abgewandelt und bearbeitet werden
- Zu den folgenden Bedingungen:
- Namensnennung – Du musst angemessene Urheber- und Rechteangaben machen, einen Link zur Lizenz beifügen und angeben, ob Änderungen vorgenommen wurden. Diese Angaben dürfen in jeder angemessenen Art und Weise gemacht werden, allerdings nicht so, dass der Eindruck entsteht, der Lizenzgeber unterstütze gerade dich oder deine Nutzung besonders.
- Weitergabe unter gleichen Bedingungen – Wenn du das Material wiedermischst, transformierst oder darauf aufbaust, musst du deine Beiträge unter der gleichen oder einer kompatiblen Lizenz wie das Original verbreiten.
Es ist erlaubt, die Datei unter den Bedingungen der GNU-Lizenz für freie Dokumentation, Version 1.2 oder einer späteren Version, veröffentlicht von der Free Software Foundation, zu kopieren, zu verbreiten und/oder zu modifizieren; es gibt keine unveränderlichen Abschnitte, keinen vorderen und keinen hinteren Umschlagtext.
Der vollständige Text der Lizenz ist im Kapitel GNU-Lizenz für freie Dokumentation verfügbar.http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue |
Ursprüngliches Datei-Logbuch
This image is a derivative work of the following images:
- Image:Butterworth_response.png licensed with Cc-by-sa-3.0,2.5,2.0,1.0, GFDL
- 2005-07-23T17:45:55Z Omegatron 1240x880 (87607 Bytes) split the cutoff frequency markers
- 2005-07-23T16:31:54Z Omegatron 1250x880 (94570 Bytes) Better butterworth filter response curve
- 2005-06-26T19:54:33Z Omegatron 250x220 (2251 Bytes) A graph or diagram made by [[User:Omegatron]]. (Uploaded with Wikimedia Commons.) Source: Created by [[User:Omegatron]] {{GFDL}}{{cc-by-sa-2.0}} [[Category:Diagrams]]\
Hochgeladen mit derivativeFX
In dieser Datei abgebildete Objekte
Motiv
image/svg+xml
09460ebc1e3325b1d79e3f2cf9a6024d339a6aad
41.638 Byte
384 Pixel
512 Pixel
Dateiversionen
Klicke auf einen Zeitpunkt, um diese Version zu laden.
Version vom | Vorschaubild | Maße | Benutzer | Kommentar | |
---|---|---|---|---|---|
aktuell | 10:50, 25. Apr. 2013 | 512 × 384 (41 KB) | wikimediacommons>Incnis Mrsi | dehyphenation |
Dateiverwendung
Die folgende Seite verwendet diese Datei:
Metadaten
Diese Datei enthält weitere Informationen, die in der Regel von der Digitalkamera oder dem verwendeten Scanner stammen. Durch nachträgliche Bearbeitung der Originaldatei können einige Details verändert worden sein.
Bildtitel | Produced by GNUPLOT 4.2 patchlevel 2-octave |
---|---|
Breite | 100% |
Höhe | 100% |